      SUBROUTINE VELO                                                     E  10
      DOUBLE PRECISION DMIN1,DEXP,DLOG,DABS                               E  20
      DOUBLE PRECISION TMRX,VPRM,HI,HR,HC,HK,WT,REC,RECH,TIM,AOPT,TITLE   E  30
      DOUBLE PRECISION DXINV,DYINV,ARINV,PORINV                           E  35
      DOUBLE PRECISION XDEL,YDEL,S,AREA,SUMT,RHO,PARAM,TEST,TOL,PINT,     E  40
     1                 HMIN,PYR                                           E  41
      DOUBLE PRECISION RATE,SLEAK,DIV                                     E  50
      COMMON /PRMJ/ NTIM,NPMP,NPNT,NITP,N,NX,NY,NP,NREC,INT,NNX,NNY,NUMO  E  60
     1BS,NMOV,IMOV,NPMAX,ITMAX,NZCRIT,IPRNT,NPTPND,NPNTMV,NPNTVL,NPNTD,N  E  70
     2PNCHV,NPDELC,ICHK                                                   E  81
      COMMON /HEDA/ THCK(40,40),PERM(40,40),TMWL(5,50),TMOBS(50),ANFCTR  SE 110
      COMMON /HEDB/ TMRX(40,40,2),VPRM(40,40),HI(40,40),HR(40,40),HC(40, SE 120
     140),HK(40,40),WT(40,40),REC(40,40),RECH(40,40),TIM(100),AOPT(20),  SE 130
     2TITLE(10),XDEL,YDEL,S,AREA,SUMT,RHO,PARAM,TEST,TOL,PINT,HMIN,PYR    E 140
      COMMON /HEDC/ MX,MY,MMX,MMY,NMX,NMY,MCHK                           SE 145
      COMMON /XINV/ DXINV,DYINV,ARINV,PORINV                              E 150
      COMMON /CHMA/ PART(3,6400),CONC(20,20),TMCN(5,50),VX(40,40),VY(40, SE 161
     140),CONINT(20,20),CNRECH(20,20),POROS,SUMTCH,BETA,TIMV,STORM,STORM SE 170
     2I,CMSIN,CMSOUT,FLMIN,FLMOT,SUMIO,CELDIS,DLTRAT,CSTORM               E 180
      COMMON /CHMC/ SUMC(20,20),VXBDY(40,40),VYBDY(40,40),PERM2(40,40)   SE 191
      COMMON /DIFUS/ DISP(20,20,4)                                        E 200
      COMMON /CHMR/ RF,DK,RHOB,THALF,DECAY,ADSORB,SORBI,DMASS1,CSTM2      E 205R
C     ***************************************************************     E 210
C     ---COMPUTE VELOCITIES AND STORE---                                  E 220
      VMAX=1.0E-10                                                        E 230
      VMAY=1.0E-10                                                        E 240
      VMXBD=1.0E-10                                                       E 250
      VMYBD=1.0E-10                                                       E 260
      TMV=TIM(N)*1.0E5                                                    E 275
      LIM=0                                                               E 280
      MAXX=0                                                              E 284
      MAXY=0                                                              E 285
      MAXVXI=0                                                            E 286
      MAXVXJ=0                                                            E 287
      MAXVYI=0                                                            E 288
      MAXVYJ=0                                                            E 289
C                                                                         E 290
      DO 20 IX=1,NX                                                       E 300
      DO 20 IY=1,NY                                                       E 310
      IF (IX.GT.NMX.OR.IY.GT.NMY) GO TO 12                               SE 315
      DO 10 IZ=1,4                                                        E 320
   10 DISP(IX,IY,IZ)=0.0                                                  E 330
C                                                                         E 340
   12 JCK=0                                                              SE 343
      IF (IX.LT.(MX-1).OR.IY.LT.(MY-1).OR.IX.GT.(MMX+1).OR.IY.GT.(MMY+1) SE 344
     1) JCK=1                                                            SE 345
      IF (THCK(IX,IY).EQ.0.0) GO TO 20                                    E 350
      RATE=REC(IX,IY)/AREA                                                E 360
      SLEAK=(HK(IX,IY)-WT(IX,IY))*VPRM(IX,IY)                             E 370
      DIV=RATE+SLEAK+RECH(IX,IY)                                          E 380
C                                                                         E 390
C        ---VELOCITIES AT NODES---                                        E 400
C           ---X-DIRECTION---                                             E 410
      PERMX=0.0                                                           E 414
      PERMD=PERM(IX,IY)+PERM(IX-1,IY)                                     E 415
      IF (PERMD.GT.0.0) PERMX=2.0*PERM(IX,IY)*PERM(IX-1,IY)/PERMD         E 416
      DHX=HK(IX-1,IY)-HK(IX+1,IY)                                         E 421
      IF (THCK(IX-1,IY).NE.0.0) GO TO 13                                  E 423
      PERMX=PERM(IX,IY)                                                   E 424
      DHX=HK(IX,IY)-HK(IX+1,IY)                                           E 425
   13 IF (THCK(IX+1,IY).NE.0.0) GO TO 14                                  E 426
      PERMX=PERM(IX-1,IY)                                                 E 427
      DHX=HK(IX-1,IY)-HK(IX,IY)                                           E 428
   14 IF (THCK(IX-1,IY).EQ.0.0.AND.THCK(IX+1,IY).EQ.0.0) DHX=0.0          E 452
      GRDX=DHX*DXINV*0.50                                                 E 455
      VX(IX,IY)=PERMX*GRDX*PORINV                                         E 461
      ABVX=ABS(VX(IX,IY))                                                 E 470
      IF (ABVX.GT.VMAX.AND.JCK.EQ.0) VMAX=ABVX                           SE 481
C           ---Y-DIRECTION---                                             E 490
      PERMY=0.0                                                           E 494
      PERMD=PERM2(IX,IY)+PERM2(IX,IY-1)                                   E 495
      IF (PERMD.GT.0.0) PERMY=2.*PERM2(IX,IY)*PERM2(IX,IY-1)/PERMD        E 496
      DHY=HK(IX,IY-1)-HK(IX,IY+1)                                         E 501
      IF (THCK(IX,IY-1).NE.0.0) GO TO 15                                  E 503
      PERMY=PERM2(IX,IY)                                                  E 504
      DHY=(HK(IX,IY)-HK(IX,IY+1))                                         E 505
   15 IF (THCK(IX,IY+1).NE.0.0) GO TO 16                                  E 506
      PERMY=PERM2(IX,IY-1)                                                E 507
      DHY=(HK(IX,IY-1)-HK(IX,IY))                                         E 508
   16 IF (THCK(IX,IY-1).EQ.0.0.AND.THCK(IX,IY+1).EQ.0.0) DHY=0.0          E 509
      GRDY=DHY*DYINV*0.50                                                 E 535
      VY(IX,IY)=PERMY*GRDY*PORINV*ANFCTR                                  E 541
      ABVY=ABS(VY(IX,IY))                                                 E 550
      IF (ABVY.GT.VMAY.AND.JCK.EQ.0) VMAY=ABVY                           SE 561
C                                                                         E 570
C        ---VELOCITIES AT CELL BOUNDARIES---                              E 580
      GRDX=(HK(IX,IY)-HK(IX+1,IY))*DXINV                                  E 590
      VXBDY(IX,IY)=PERM(IX,IY)*GRDX*PORINV                                E 611
      GRDY=(HK(IX,IY)-HK(IX,IY+1))*DYINV                                  E 620
      VYBDY(IX,IY)=PERM2(IX,IY)*GRDY*PORINV*ANFCTR                        E 641
      IF (JCK.EQ.0) THEN                                                 SE 645
      ABVX=ABS(VXBDY(IX,IY))                                              E 650
      ABVY=ABS(VYBDY(IX,IY))                                              E 660
       IF (ABVX.GT.VMXBD) THEN                                            E 672
         VMXBD=ABVX                                                       E 673
         MAXVXI=IX                                                        E 674
         MAXVXJ=IY                                                        E 675
       END IF                                                             E 676
       IF (ABVY.GT.VMYBD) THEN                                            E 682
         VMYBD=ABVY                                                       E 683
         MAXVYI=IX                                                        E 684
         MAXVYJ=IY                                                        E 685
       END IF                                                             E 686
      END IF                                                             SE 687
C                                                                         E 690
      IF (DIV.GE.0.0) GO TO 20                                            E 700
      IF (JCK.GT.0) GO TO 20                                             SE 705
      TDIV=(POROS*THCK(IX,IY)*RF)/DABS(DIV)                               E 711R
      IF (TDIV.GE.TMV) GO TO 20                                           E 722
      TMV=TDIV                                                            E 724
      MAXX=IX                                                             E 725
      MAXY=IY                                                             E 726
   20 CONTINUE                                                            E 730
C     ***************************************************************     E 740
C     ---PRINT VELOCITIES---                                              E 750
      IF (NPNTVL.EQ.0) GO TO 80                                           E 760
      IF (NPNTVL.EQ.2) GO TO 30                                           E 770
      IF (NPNTVL.EQ.1.AND.N.EQ.1) GO TO 30                                E 780
      GO TO 80                                                            E 790
   30 WRITE (6,320)                                                       E 800
      WRITE (6,330)                                                       E 810
      DO 40 IY=1,NY                                                       E 820
   40 WRITE (6,350) (VX(IX,IY),IX=1,NX)                                   E 830
      WRITE (6,340)                                                       E 840
      DO 50 IY=1,NY                                                       E 850
   50 WRITE (6,350) (VXBDY(IX,IY),IX=1,NX)                                E 860
      WRITE (6,360)                                                       E 870
      WRITE (6,330)                                                       E 880
      DO 60 IY=1,NY                                                       E 890
   60 WRITE (6,350) (VY(IX,IY),IX=1,NX)                                   E 900
      WRITE (6,340)                                                       E 910
      DO 70 IY=1,NY                                                       E 920
   70 WRITE (6,350) (VYBDY(IX,IY),IX=1,NX)                                E 930
C     ---PUNCH VELOCITIES---                                              E 940
   80 IF (NPNCHV.EQ.0) GO TO 110                                          E 950
      IF (NPNCHV.EQ.2) GO TO 90                                           E 960
      IF (NPNCHV.EQ.1.AND.N.EQ.1) GO TO 90                                E 970
      GO TO 110                                                           E 980
   90 WRITE (7,510) NX,NY,XDEL,YDEL,VMAX,VMAY                             E 990
      DO 100 IY=1,NY                                                      E1000
      WRITE (7,520) (VX(IX,IY),IX=1,NX)                                   E1010
  100 WRITE (7,520) (VY(IX,IY),IX=1,NX)                                   E1020
C     ****************************************************************    E1030
C     ---COMPUTE NEXT TIME STEP---                                        E1040
  110 WRITE (6,390)                                                       E1050
      WRITE (6,410) VMXBD,VMYBD                                           E1070
      IF (RF.LE.1.0) GO TO 115                                            E1071R
      VMXBD=VMXBD/RF                                                      E1075R
      VMYBD=VMYBD/RF                                                      E1076R
      WRITE (6,394) VMXBD,VMYBD                                           E1079R
  115 TDELXB=CELDIS*XDEL/VMXBD                                            E1082R
      TDELYB=CELDIS*YDEL/VMYBD                                            E1110
      ITCD=0                                                              E1111
      IF (TDELYB.LT.TDELXB) ITCD=1                                        E1112
      TIMV=AMIN1(TDELXB,TDELYB)                                           E1121
      IF (AMAX1(VMXBD,VMYBD).LE.1.0E-10) WRITE(6,570)                     E1126
      WRITE (6,310) TMV,TIMV                                              E1130
      IF (TMV.LT.TIMV) GO TO 120                                          E1140
      LIM=-1                                                              E1150
      GO TO 130                                                           E1160
  120 TIMV=TMV                                                            E1170
      LIM=1                                                               E1180
  130 NTIMV=TIM(N)/TIMV                                                   E1190
      NMOV=NTIMV+1                                                        E1200
      WRITE (6,420) TIMV,NTIMV,NMOV                                       E1210
      TIMV=TIM(N)/NMOV                                                    E1220
      WRITE (6,370) TIM(N)                                                E1230
      WRITE (6,380) TIMV                                                  E1240
C                                                                         E1250
      IF (BETA.EQ.0.0) GO TO 200                                          E1260
C     ****************************************************************    E1270
C     ---COMPUTE DISPERSION COEFFICIENTS---                               E1280
      ALPHA=BETA                                                          E1290
      ALNG=ALPHA                                                          E1300
      TRAN=DLTRAT*ALPHA                                                   E1310
      XX2=XDEL*XDEL                                                       E1320
      YY2=YDEL*YDEL                                                       E1330
      XY2=4.0*XDEL*YDEL                                                   E1340
      DO 150 IX=2,MMX                                                    SE1351
      DO 150 IY=2,MMY                                                    SE1361
      IF (THCK(IX,IY).EQ.0.0) GO TO 150                                   E1370
      JX=IX-MX+1                                                         SE1375
      JY=IY-MY+1                                                         SE1376
      IF (JX.LT.1.OR.JY.LT.1) GO TO 150                                  SE1377
      VXE=VXBDY(IX,IY)                                                    E1380
      VYS=VYBDY(IX,IY)                                                    E1390
      IF (THCK(IX+1,IY).EQ.0.0) GO TO 140                                 E1400
      IF ((IX+1).GT.MMX) GO TO 140                                       SE1405
C        ---FORWARD COEFFICIENTS: X-DIRECTION---                          E1410
      VYE=(VYBDY(IX,IY-1)+VYBDY(IX+1,IY-1)+VYS+VYBDY(IX+1,IY))/4.0        E1420
      VXE2=VXE*VXE                                                        E1430
      VYE2=VYE*VYE                                                        E1440
      VMGE=SQRT(VXE2+VYE2)                                                E1450
      IF (VMGE.LT.1.0E-20) GO TO 140                                      E1460
      DALN=ALNG*VMGE                                                      E1470
      DTRN=TRAN*VMGE                                                      E1480
      VMGE2=VMGE*VMGE                                                     E1490
C           ---XX COEFFICIENT---                                          E1500
      DISP(JX,JY,1)=(DALN*VXE2+DTRN*VYE2)/(VMGE2*XX2)                    SE1511
C           ---XY COEFFICIENT---                                          E1520
      IF ((IY-1).LT.MY.OR.(IY+1).GT.MMY) GO TO 140                       SE1525
      DISP(JX,JY,3)=(DALN-DTRN)*VXE*VYE/(VMGE2*XY2)                      SE1531
C        ---FORWARD COEFFICIENTS: Y-DIRECTION---                          E1540
  140 IF (THCK(IX,IY+1).EQ.0.0) GO TO 150                                 E1550
      IF ((IY+1).GT.MMY) GO TO 150                                       SE1555
      VXS=(VXBDY(IX-1,IY)+VXE+VXBDY(IX-1,IY+1)+VXBDY(IX,IY+1))/4.0        E1560
      VYS2=VYS*VYS                                                        E1570
      VXS2=VXS*VXS                                                        E1580
      VMGS=SQRT(VXS2+VYS2)                                                E1590
      IF (VMGS.LT.1.0E-20) GO TO 150                                      E1600
      DALN=ALNG*VMGS                                                      E1610
      DTRN=TRAN*VMGS                                                      E1620
      VMGS2=VMGS*VMGS                                                     E1630
C           ---YY COEFFICIENT---                                          E1640
      DISP(JX,JY,2)=(DALN*VYS2+DTRN*VXS2)/(VMGS2*YY2)                    SE1651
C           ---YX COEFFICIENT---                                          E1660
      IF ((IX-1).LT.MX.OR.(IX+1).GT.MMX) GO TO 150                       SE1665
      DISP(JX,JY,4)=(DALN-DTRN)*VXS*VYS/(VMGS2*XY2)                      SE1671
  150 CONTINUE                                                            E1680
C     ****************************************************************    E1690
C     ---ADJUST CROSS-PRODUCT TERMS FOR ZERO THICKNESS---                 E1700
      DO 160 IX=2,MMX                                                    SE1711
      DO 160 IY=2,MMY                                                    SE1721
      JX=IX-MX+1                                                         SE1725
      JY=IY-MY+1                                                         SE1726
      IF (JX.LT.1.OR.JY.LT.1) GO TO 160                                  SE1727
      IF (THCK(IX,IY+1).EQ.0.0.OR.THCK(IX+1,IY+1).EQ.0.0.OR.THCK(IX,IY-1  E1730
     1).EQ.0.0.OR.THCK(IX+1,IY-1).EQ.0.0) DISP(JX,JY,3)=0.0              SE1741
      IF (THCK(IX+1,IY).EQ.0.0.OR.THCK(IX+1,IY+1).EQ.0.0.OR.THCK(IX-1,IY  E1750
     1).EQ.0.0.OR.THCK(IX-1,IY+1).EQ.0.0) DISP(JX,JY,4)=0.0              SE1761
  160 CONTINUE                                                            E1770
C     ****************************************************************    E1780
C     ---CHECK FOR STABILITY OF EXPLICIT METHOD---                        E1790
      TIMDIS=0.0                                                          E1800
      DO 170 IX=1,NMX                                                    SE1811
      DO 170 IY=1,NMY                                                    SE1821
      TDCO=(DISP(IX,IY,1)+DISP(IX,IY,2))/RF                               E1831R
  170 IF (TDCO.GT.TIMDIS) TIMDIS=TDCO                                     E1840
      TIMDC=0.5/TIMDIS                                                    E1850
      WRITE (6,440) TIMDC                                                 E1860
      NTIMD=TIM(N)/TIMDC                                                  E1870
      NDISP=NTIMD+1                                                       E1880
      IF (NDISP.LE.NMOV) GO TO 180                                        E1890
      NMOV=NDISP                                                          E1900
      TIMV=TIM(N)/NMOV                                                    E1910
      LIM=0                                                               E1920
  180 WRITE (6,430) TIMV,NTIMD,NMOV                                       E1930
C     ****************************************************************    E1940
C     ---ADJUST DISP. EQUATION COEFFICIENTS FOR SATURATED THICKNESS---    E1950
      DO 190 IX=2,MMX                                                    SE1961
      DO 190 IY=2,MMY                                                    SE1971
      IF (THCK(IX,IY).EQ.0.0) GO TO 190                                   E1972
      JX=IX-MX+1                                                         SE1973A
      JY=IY-MY+1                                                         SE1973B
      IF (JX.LT.1.OR.JY.LT.1) GO TO 190                                  SE1973C
      BAVX=2.0*THCK(IX,IY)*THCK(IX+1,IY)/(THCK(IX,IY)+THCK(IX+1,IY))      E1974
      BAVY=2.0*THCK(IX,IY)*THCK(IX,IY+1)/(THCK(IX,IY)+THCK(IX,IY+1))      E1976
      DISP(JX,JY,1)=DISP(JX,JY,1)*BAVX                                   SE2001
      DISP(JX,JY,2)=DISP(JX,JY,2)*BAVY                                   SE2011
      DISP(JX,JY,3)=DISP(JX,JY,3)*BAVX                                   SE2021
      DISP(JX,JY,4)=DISP(JX,JY,4)*BAVY                                   SE2033
  190 CONTINUE                                                            E2034
C     ****************************************************************    E2040
  200 IF (NMOV.EQ.1) GO TO 235                                            E2052
      IF (LIM) 210,220,230                                                E2054
  210 WRITE (6,530)                                                       E2060
      IF (ITCD.GT.0) THEN                                                 E2062
         MJ=MAXVYJ+1                                                      E2063
         WRITE (6,534) MAXVYI,MAXVYJ,MAXVYI,MJ                            E2064
       ELSE                                                               E2065
         MI=MAXVXI+1                                                      E2066
         WRITE (6,535) MAXVXI,MAXVXJ,MI,MAXVXJ                            E2067
      END IF                                                              E2068
      GO TO 240                                                           E2070
  220 WRITE (6,540)                                                       E2080
      GO TO 240                                                           E2090
  230 WRITE (6,550)                                                       E2100
      WRITE (6,560) MAXX,MAXY                                             E2102
      GO TO 240                                                           E2104
  235 WRITE (6,580)                                                       E2106
C     ****************************************************************    E2110
C     ---PRINT DISPERSION EQUATION COEFFICIENTS---                        E2120
  240 IF (NPNTD.EQ.0) GO TO 300                                           E2130
      IF (NPNTD.EQ.2) GO TO 250                                           E2140
      IF (NPNTD.EQ.1.AND.N.EQ.1) GO TO 250                                E2150
      GO TO 300                                                           E2160
  250 WRITE (6,450)                                                       E2170
      WRITE (6,460)                                                       E2180
      DO 260 IY=1,NMY                                                    SE2191
  260 WRITE (6,500) (DISP(IX,IY,1),IX=1,NMX)                             SE2201
      WRITE (6,470)                                                       E2210
      DO 270 IY=1,NMY                                                    SE2221
  270 WRITE (6,500) (DISP(IX,IY,2),IX=1,NMX)                             SE2231
      WRITE (6,480)                                                       E2240
      DO 280 IY=1,NMY                                                    SE2251
  280 WRITE (6,500) (DISP(IX,IY,3),IX=1,NMX)                             SE2261
      WRITE (6,490)                                                       E2270
      DO 290 IY=1,NMY                                                    SE2281
  290 WRITE (6,500) (DISP(IX,IY,4),IX=1,NMX)                             SE2291
C     ****************************************************************    E2300
  300 RETURN                                                              E2310
C     ****************************************************************    E2320
C                                                                         E2330
C                                                                         E2340
C                                                                         E2350
  310 FORMAT (1H0,19H TMV (MAX. INJ.) = ,G12.5/20H  TIMV (CELDIS)   = ,G  E2361R
     112.5)                                                               E2370
  320 FORMAT (1H1,12HX VELOCITIES)                                        E2380
  330 FORMAT (1H ,25X,8HAT NODES/)                                        E2390
  340 FORMAT (1H0,25X,13HON BOUNDARIES/)                                  E2400
  350 FORMAT (1H ,1P10E12.3)                                              E2411
  360 FORMAT (1H1,12HY VELOCITIES)                                        E2420
  370 FORMAT (3H   ,11HTIM (N)  = ,1G12.5)                                E2430
  380 FORMAT (3H   ,11HTIMEVELO = ,1G12.5)                                E2440
  390 FORMAT (1H1,10X,29HSTABILITY CRITERIA --- M.O.C.//)                 E2450
  394 FORMAT (1H0,5X,46HMAXIMUM EFFECTIVE SOLUTE VELOCITIES:  X-VEL = ,   E2453R
     1  1PE9.2,5X,8HY-VEL = ,1PE9.2)                                      E2454R
  410 FORMAT (1H0,5X,35HMAXIMUM FLUID VELOCITIES:  X-VEL = ,1PE9.2,5X,    E2471
     1  8HY-VEL = ,1PE9.2)                                                E2472
  420 FORMAT (1H0,8H TIMV = ,1PE9.2,5X,8HNTIMV = ,I5,5X,7HNMOV = ,I5/)    E2480
  430 FORMAT (1H0,8H TIMV = ,1PE9.2,5X,8HNTIMD = ,I5,5X,7HNMOV = ,I5)     E2490
  440 FORMAT (3H   ,11HTIMEDISP = ,1E12.5)                                E2500
  450 FORMAT (1H1,32HDISPERSION EQUATION COEFFICIENTS,10X,25H=(D-IJ)*(B)  E2510
     1/(GRID FACTOR))                                                     E2520
  460 FORMAT (1H0,35X,14HXX COEFFICIENT/)                                 E2531
  470 FORMAT (1H0,35X,14HYY COEFFICIENT/)                                 E2541
  480 FORMAT (1H0,35X,14HXY COEFFICIENT/)                                 E2551
  490 FORMAT (1H0,35X,14HYX COEFFICIENT/)                                 E2561
  500 FORMAT (1H ,1P10E11.2)                                              E2571
  510 FORMAT (2I4,2F10.1,2F10.7)                                          E2580
  520 FORMAT (8F10.7)                                                     E2590
  530 FORMAT (1H0,10X,42HTHE LIMITING STABILITY CRITERION IS CELDIS)      E2600
  534 FORMAT (1H ,4X,52HMAX. Y-VEL. IS CONSTRAINT AND OCCURS BETWEEN NOD  E2602
     1ES (,I2,1H,,I2,7H) AND (,I2,1H,,I2,1H))                             E2603
  535 FORMAT (1H ,4X,52HMAX. X-VEL. IS CONSTRAINT AND OCCURS BETWEEN NOD  E2604
     1ES (,I2,1H,,I2,7H) AND (,I2,1H,,I2,1H))                             E2605
  540 FORMAT (1H0,10X,40HTHE LIMITING STABILITY CRITERION IS BETA)        E2610
  550 FORMAT (1H0,10X,58HTHE LIMITING STABILITY CRITERION IS MAXIMUM INJ  E2620
     1ECTION RATE)                                                        E2630
  560 FORMAT (1H ,15X,35HMAX. INJECTION OCCURS AT CELL IX = ,I3,7H  IY =  E2635
     1 ,I3)                                                               E2636
  570 FORMAT (1H0,5X,47H*** WARNING ***  DECREASE CRITERIA IN E 230-260)  E2637
  580 FORMAT (1H0,10X,63H*TIME INCREMENT FOR SOLUTE TRANSPORT EQUALS TIM  E2638
     1E STEP FOR FLOW*)                                                   E2639
      END                                                                 E2640-
